#!/usr/bin/perl
# xapian-omega search engine plugin
package IkiWiki::Plugin::search;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type => "getsetup", id => "search", call => \&getsetup);
	hook(type => "checkconfig", id => "search", call => \&checkconfig);
	hook(type => "pagetemplate", id => "search", call => \&pagetemplate);
	hook(type => "indexhtml", id => "search", call => \&indexhtml);
	hook(type => "delete", id => "search", call => \&delete);
	hook(type => "cgi", id => "search", call => \&cgi);
	hook(type => "sessioncgi", id => "search", call => \&sessioncgi);
	hook(type => "disable", id => "search", call => \&disable);
	hook(type => "needsbuild", id => "search", call => \&needsbuild);
		
	eval q{ use Search::Xapian }; # load early to work around #622591
}

sub getsetup () {
	return
		plugin => {
			safe => 1,
			rebuild => 1,
			section => "web",
		},
		omega_cgi => {
			type => "string",
			example => "/usr/lib/cgi-bin/omega/omega",
			description => "path to the omega cgi program",
			safe => 0, # external program
			rebuild => 0,
		},
		google_search => {
			type => "booblean",
			example => 1,
			description => "use google site search rather than internal xapian index?",
			safe => 1,
			rebuild => 0,
		},
}

sub checkconfig () {
	foreach my $required (qw(url cgiurl)) {
		if (! length $config{$required}) {
			error(sprintf(gettext("Must specify %s when using the %s plugin"), $required, 'search'));
		}
	}
	
	if (! defined $config{omega_cgi}) {
		$config{omega_cgi}="/usr/lib/cgi-bin/omega/omega";
	}

	# Parsing "search"
	my @search = ();
	if (defined $config{search_db}
	 and   (ref($config{search_db}) eq "ARRAY")) {
		my $length = $#{$config{search_db}}+1;
		my $columns = 4;
		if (($length % $columns) != 0) {
			error("config{search_db} length($length) must be a multiple of $columns.");
		 }
		for(my $row = 0; $row < $length/$columns; $row++) {
			my ($db, $auth, $dest, $index)
			 = @{$config{search_db}}[($columns*$row+0)..($columns*($row+1))];
			my $auth_yesno = IkiWiki::yesno($auth);
			push @search,
			 { db    => $db
			 , auth  => $auth_yesno
			 , dest  => $dest
			 , index => $index
			 };
		 }
	 }
	$config{search} = \@search;

	# This is a mass dependency, so if the search form template
	# changes, every page is rebuilt.
	add_depends("", "templates/searchform.tmpl");
}

my $form = {};
sub pagetemplate (@) {
	my %params=@_;
	my $page=$params{page};
	my $template=$params{template};

	my @search = grep {
		pagespec_match($page, $_->{dest})
	 } @{$config{search}};

	# Add search box to page header.
	if (@search > 0 and $template->query(name => "searchform")) {
		my $form_id = join(' ', (map {$_->{db}} @search));
		if (! defined $form->{$form_id}) {
			my $searchform = template("searchform.tmpl", blind_cache => 1);
			$searchform->param(searchaction => IkiWiki::cgiurl());
			$searchform->param(searchdb => [map {{db=>$_->{db}}} @search]);
			$searchform->param(html5 => $config{html5});
			$form->{$form_id}=$searchform->output;
		 }
		$template->param(searchform => $form->{$form_id});
	 }
}

my $scrubber;
my $stemmer;
sub indexhtml (@) {
	my %params=@_;

	return if $config{google_search};

	setupfiles();

	# A unique pageterm is used to identify the document for a page.
	my $pageterm=pageterm($params{page});
	return unless defined $pageterm;
	my $search = (grep {
		pagespec_match($params{page}, $_->{index})
	 } @{$config{search}})[0];
	return unless defined $search;
	
	my $db=xapiandb($search->{db});
	my $doc=Search::Xapian::Document->new();
	my $caption=pagetitle($params{page});
	my $title;
	if (exists $pagestate{$params{page}}{meta} &&
		exists $pagestate{$params{page}}{meta}{title}) {
		$title=$pagestate{$params{page}}{meta}{title};
	}
	else {
		$title=$caption;
	}

	# Remove html from text to be indexed.
	if (! defined $scrubber) {
		eval q{use HTML::Scrubber};
		if (! $@) {
			$scrubber=HTML::Scrubber->new(allow => []);
		}
	}
	my $toindex = defined $scrubber ? $scrubber->scrub($params{content}) : $params{content};
	
	# Take 512 characters for a sample, then extend it out
	# if it stopped in the middle of a word.
	my $size=512;
	my ($sample)=substr($toindex, 0, $size);
	if (length($sample) == $size) {
		my $max=length($toindex);
		my $next;
		while ($size < $max &&
		       ($next=substr($toindex, $size++, 1)) !~ /\s/) {
			$sample.=$next;
		}
	}
	$sample=~s/\n/ /g;
	
	my $url=urlto($params{destpage}, "");
	if (defined $pagestate{$params{page}}{meta}{permalink}) {
		$url=$pagestate{$params{page}}{meta}{permalink}
	}

	# data used by omega
	# Decode html entities in it, since omega re-encodes them.
	eval q{use HTML::Entities};
	error $@ if $@;
	$doc->set_data(
		"url=".$url."\n".
		"sample=".decode_entities($sample)."\n".
		"caption=".decode_entities($caption)."\n".
		"modtime=$IkiWiki::pagemtime{$params{page}}\n".
		"size=".length($params{content})."\n"
	);

	# Index document and add terms for other metadata.
	my $tg = Search::Xapian::TermGenerator->new();
	if (! $stemmer) {
		my $langcode=$ENV{LANG} || "en";
		$langcode=~s/_.*//;

		# This whitelist is here to work around a xapian bug (#486138)
		my @whitelist=qw{da de en es fi fr hu it no pt ru ro sv tr};

		if (grep { $_ eq $langcode } @whitelist) {
			$stemmer=Search::Xapian::Stem->new($langcode);
		}
		else {
			$stemmer=Search::Xapian::Stem->new("english");
		}
	}
	$tg->set_stemmer($stemmer);
	$tg->set_document($doc);
	$tg->index_text($params{page}, 2);
	$tg->index_text($caption, 2);
	$tg->index_text($title, 2) if $title ne $caption;
	$tg->index_text($toindex);
	$tg->index_text(lc($title), 1, "S"); # for title:foo
	foreach my $link (@{$links{$params{page}}}) {
		$tg->index_text(lc($link), 1, "XLINK"); # for link:bar
	}

	$doc->add_term($pageterm);
	$db->replace_document_by_term($pageterm, $doc);
}

sub delete (@) {
	return if $config{google_search};

	foreach my $page (@_) {
		my $pageterm=pageterm(pagename($page));
		foreach my $search (@{$config{search}}) {
			my $db=xapiandb($search->{db});
			$db->delete_document_by_term($pageterm)
				if defined $pageterm;
		 }
	 }
}

sub cgi ($) {
	my $cgi=shift;

	if (defined $cgi->param('P')) {
		if ($config{google_search}) {
			print $cgi->redirect("https://www.google.com/search?sitesearch=$config{url}&q=".$cgi->param('P'));
			exit 0;
		 }
		else {
			if (defined $cgi->param('DB')) {
				my @db = map {split('/', $_)} ($cgi->param('DB'));
				my @search = map {
					my $db = $_;
					grep { $db eq $_->{db} } @{$config{search}};
				 } @db;
				my $auth_needed = 0;
				foreach (@search) {
					if ($_->{auth}) {
						$auth_needed = 1;
						last;
					 }
				 }
				if (not $auth_needed) {
					# only works for GET requests
					chdir("$config{wikistatedir}/xapian") || error("chdir: $!");
					$ENV{OMEGA_CONFIG_FILE}="./omega.conf";
					$ENV{CGIURL}=IkiWiki::cgiurl();
					IkiWiki::loadindex();
					$ENV{HELPLINK}=htmllink("", "", "ikiwiki/searching",
						noimageinline => 1, linktext => "Help");
					exec($config{omega_cgi}) || error("$config{omega_cgi} failed: $!");
				 }
			 }
		 }
	 }
}

sub sessioncgi ($) {
	my $cgi=shift;
	my $session=shift;
	
	if ($cgi->param('do') eq 'search') {
		eval q{use CGI qw(-oldstyle_urls)};
			# NOTE: ampersands separators are required for xapian-omega
		IkiWiki::needsignin($cgi, $session);
		IkiWiki::cgi_savesession($session);
		my $headers;
		do {
			open(my $STDOUT_diverted, '>', \$headers) or die;
			my $STDOUT_original = select $STDOUT_diverted;
			IkiWiki::printheader($session);
			select $STDOUT_original;
			close $STDOUT_diverted;
			local $/ = "\r\n";
			chomp $headers;
		 };
		print $headers;
		chdir("$config{wikistatedir}/xapian") || error("chdir: $!");
		$ENV{OMEGA_CONFIG_FILE}="./omega.conf";
		$ENV{CGIURL}=IkiWiki::cgiurl();
		$ENV{REQUEST_METHOD}='GET';
		$ENV{QUERY_STRING}=$cgi->query_string();
		IkiWiki::loadindex();
		$ENV{HELPLINK}=htmllink("", "", "ikiwiki/searching",
			noimageinline => 1, linktext => "Help");
		exec($config{omega_cgi}) || error("$config{omega_cgi} failed: $!");
	 }
}

sub pageterm ($) {
	my $page=shift;

	# 240 is the number used by omindex to decide when to hash an
	# overlong term. This does not use a compatible hash method though.
	eval q{use Encode};
	if (length encode_utf8($page) > 240) {
		eval q{use Digest::SHA};
		if ($@) {
			debug("search: ".sprintf(gettext("need Digest::SHA to index %s"), $page)) if $@;
			return undef;
		}

		# Note no colon, therefore it's guaranteed to not overlap
		# with a page with the same name as the hash..
		return "U".lc(Digest::SHA::sha1_hex($page));
	}
	else {
		return "U:".$page;
	}
}

my $db = {};
sub xapiandb ($) {
	my ($dbname) = @_;
	if (! defined $db->{$dbname}) {
		eval q{
			use Search::Xapian;
			use Search::Xapian::WritableDatabase;
		};
		error($@) if $@;
		$db->{$dbname}=Search::Xapian::WritableDatabase->new($config{wikistatedir}."/xapian/".$dbname,
			Search::Xapian::DB_CREATE_OR_OPEN());
	}
	return $db->{$dbname};
}

{
my $setup=0;
sub setupfiles () {
	if (! $setup and (! -e $config{wikistatedir}."/xapian" || $config{rebuild})) {
		writefile("omega.conf", $config{wikistatedir}."/xapian",
			"database_dir .\n".
			"template_dir ./templates\n");
		omega_template();	
		$setup=1;
	}
}
}

sub needsbuild {
	my $list=shift;
	if (grep {
		$_ eq "templates/page.tmpl" ||
		$_ eq "templates/searchquery.tmpl"
	} @$list) {
		omega_template();
	}
}

sub omega_template {
	# Avoid omega interpreting anything in the cgitemplate
	# as an omegascript command.
	eval q{use IkiWiki::CGI};
	my $template=IkiWiki::cgitemplate(undef, gettext("search"), "\0",
		searchform => "", # avoid showing the small search form
	);
	eval q{use HTML::Entities};
	error $@ if $@;
	$template=encode_entities($template, '\$');

	my $querytemplate=readfile(IkiWiki::template_file("searchquery.tmpl"));
	$template=~s/\0/$querytemplate/;
	writefile("query", $config{wikistatedir}."/xapian/templates",
		$template);
}

sub disable () {
	if (-d $config{wikistatedir}."/xapian") {
		system("rm", "-rf", $config{wikistatedir}."/xapian");
	}
}

1
