maintenance/postgres/compare_schemas.pl

   1 #!/usr/bin/perl
   2
   3 ## Rough check that the base and postgres "tables.sql" are in sync
   4 ## Should be run from maintenance/postgres
   5
   6 use strict;
   7 use warnings;
   8 use Data::Dumper;
   9
  10 my @old = ('../tables.sql');
  11 my $new = 'tables.sql';
  12 my @xfile;
  13
  14 ## Read in exceptions and other metadata
  15 my %ok;
  16 while (<DATA>) {
  17         next unless /^(\w+)\s*:\s*([^#]+)/;
  18         my ($name,$val) = ($1,$2);
  19         chomp $val;
  20         if ($name eq 'RENAME') {
  21                 die "Invalid rename\n" unless $val =~ /(\w+)\s+(\w+)/;
  22                 $ok{OLD}{$1} = $2;
  23                 $ok{NEW}{$2} = $1;
  24                 next;
  25         }
  26         if ($name eq 'XFILE') {
  27                 push @xfile, $val;
  28                 next;
  29         }
  30         for (split /\s+/ => $val) {
  31                 $ok{$name}{$_} = 0;
  32         }
  33 }
  34
  35 my $datatype = join '|' => qw(
  36 bool
  37 tinyint int bigint real float
  38 tinytext mediumtext text char varchar varbinary binary
  39 timestamp datetime
  40 tinyblob mediumblob blob
  41 );
  42 $datatype .= q{|ENUM\([\"\w, ]+\)};
  43 $datatype = qr{($datatype)};
  44
  45 my $typeval = qr{(\(\d+\))?};
  46
  47 my $typeval2 = qr{ unsigned| binary| NOT NULL| NULL| auto_increment| default ['\-\d\w"]+| REFERENCES .+CASCADE};
  48
  49 my $indextype = join '|' => qw(INDEX KEY FULLTEXT), 'PRIMARY KEY', 'UNIQUE INDEX', 'UNIQUE KEY';
  50 $indextype = qr{$indextype};
  51
  52 my $engine = qr{TYPE|ENGINE};
  53
  54 my $tabletype = qr{InnoDB|MyISAM|HEAP|HEAP MAX_ROWS=\d+|InnoDB MAX_ROWS=\d+ AVG_ROW_LENGTH=\d+};
  55
  56 my $charset = qr{utf8|binary};
  57
  58 open my $newfh, '<', $new or die qq{Could not open $new: $!\n};
  59
  60
  61 my ($table,%old);
  62
  63 ## Read in the xfiles
  64 my %xinfo;
  65 for my $xfile (@xfile) {
  66         print "Loading $xfile\n";
  67         my $info = &parse_sql($xfile);
  68         for (keys %$info) {
  69                 $xinfo{$_} = $info->{$_};
  70         }
  71 }
  72
  73 for my $oldfile (@old) {
  74         print "Loading $oldfile\n";
  75         my $info = &parse_sql($oldfile);
  76         for (keys %xinfo) {
  77                 $info->{$_} = $xinfo{$_};
  78         }
  79         $old{$oldfile} = $info;
  80 }
  81
  82 sub parse_sql {
  83
  84         my $oldfile = shift;
  85
  86         open my $oldfh, '<', $oldfile or die qq{Could not open $oldfile: $!\n};
  87
  88         my %info;
  89         while (<$oldfh>) {
  90                 next if /^\s*\-\-/ or /^\s+$/;
  91                 s/\s*\-\- [\w ]+$//;
  92                 chomp;
  93
  94                 if (/CREATE\s*TABLE/i) {
  95                         m{^CREATE TABLE /\*\$wgDBprefix\*/(\w+) \($}
  96                                 or die qq{Invalid CREATE TABLE at line $. of $oldfile\n};
  97                         $table = $1;
  98                         $info{$table}{name}=$table;
  99                 }
 100                 elsif (m#^\) /\*\$wgDBTableOptions\*/#) {
 101                         $info{$table}{engine} = 'TYPE';
 102                         $info{$table}{type} = 'variable';
 103                 }
 104                 elsif (/^\) ($engine)=($tabletype);$/) {
 105                         $info{$table}{engine}=$1;
 106                         $info{$table}{type}=$2;
 107                 }
 108                 elsif (/^\) ($engine)=($tabletype), DEFAULT CHARSET=($charset);$/) {
 109                         $info{$table}{engine}=$1;
 110                         $info{$table}{type}=$2;
 111                         $info{$table}{charset}=$3;
 112                 }
 113                 elsif (/^  (\w+) $datatype$typeval$typeval2{0,3},?$/) {
 114                         $info{$table}{column}{$1} = $2;
 115                         my $extra = $3 || '';
 116                         $info{$table}{columnfull}{$1} = "$2$extra";
 117                 }
 118                 elsif (/^  ($indextype)(?: (\w+))? \(([\w, \(\)]+)\),?$/) {
 119                         $info{$table}{lc $1.'_name'} = $2 ? $2 : '';
 120                         $info{$table}{lc $1.'pk_target'} = $3;
 121                 }
 122                 else {
 123                         die "Cannot parse line $. of $oldfile:\n$_\n";
 124                 }
 125
 126         }
 127         close $oldfh;
 128
 129         return \%info;
 130
 131 } ## end of parse_sql
 132
 133 ## Read in the parser test information
 134 my $parsefile = '../parserTests.inc';
 135 open my $pfh, '<', $parsefile or die qq{Could not open "$parsefile": $!\n};
 136 my $stat = 0;
 137 my %ptable;
 138 while (<$pfh>) {
 139         if (!$stat) {
 140                 if (/function listTables/) {
 141                         $stat = 1;
 142                 }
 143                 next;
 144         }
 145         $ptable{$1}=2 while /'(\w+)'/g;
 146         last if /\);/;
 147 }
 148 close $pfh;
 149
 150 my $OK_NOT_IN_PTABLE = '
 151 filearchive
 152 logging
 153 profiling
 154 querycache_info
 155 searchindex
 156 trackbacks
 157 transcache
 158 user_newtalk
 159 ';
 160
 161 ## Make sure all tables in main tables.sql are accounted for int the parsertest.
 162 for my $table (sort keys %{$old{'../tables.sql'}}) {
 163         $ptable{$table}++;
 164         next if $ptable{$table} > 2;
 165         next if $OK_NOT_IN_PTABLE =~ /\b$table\b/;
 166         print qq{Table "$table" is in the schema, but not used inside of parserTest.inc\n};
 167 }
 168 ## Any that are used in ptables but no longer exist in the schema?
 169 for my $table (sort grep { $ptable{$_} == 2 } keys %ptable) {
 170         print qq{Table "$table" ($ptable{$table}) used in parserTest.inc, but not found in schema\n};
 171 }
 172
 173 for my $oldfile (@old) {
 174
 175 ## Begin non-standard indent
 176
 177 ## MySQL sanity checks
 178 for my $table (sort keys %{$old{$oldfile}}) {
 179         my $t = $old{$oldfile}{$table};
 180         if (($oldfile =~ /5/ and $t->{engine} ne 'ENGINE')
 181                 or
 182                 ($oldfile !~ /5/ and $t->{engine} ne 'TYPE')) {
 183                 die "Invalid engine for $oldfile: $t->{engine}\n" unless $t->{name} eq 'profiling';
 184         }
 185         my $charset = $t->{charset} || '';
 186         if ($oldfile !~ /binary/ and $charset eq 'binary') {
 187                 die "Invalid charset for $oldfile: $charset\n";
 188         }
 189 }
 190
 191 my $dtype = join '|' => qw(
 192 SMALLINT INTEGER BIGINT NUMERIC SERIAL
 193 TEXT CHAR VARCHAR
 194 BYTEA
 195 TIMESTAMPTZ
 196 CIDR
 197 );
 198 $dtype = qr{($dtype)};
 199 my %new;
 200 my ($infunction,$inview,$inrule,$lastcomma) = (0,0,0,0);
 201 seek $newfh, 0, 0;
 202 while (<$newfh>) {
 203         next if /^\s*\-\-/ or /^\s*$/;
 204         s/\s*\-\- [\w ']+$//;
 205         next if /^BEGIN;/ or /^SET / or /^COMMIT;/;
 206         next if /^CREATE SEQUENCE/;
 207         next if /^CREATE(?: UNIQUE)? INDEX/;
 208         next if /^CREATE FUNCTION/;
 209         next if /^CREATE TRIGGER/ or /^  FOR EACH ROW/;
 210         next if /^INSERT INTO/ or /^  VALUES \(/;
 211         next if /^ALTER TABLE/;
 212         chomp;
 213
 214         if (/^\$mw\$;?$/) {
 215                 $infunction = $infunction ? 0 : 1;
 216                 next;
 217         }
 218         next if $infunction;
 219
 220         next if /^CREATE VIEW/ and $inview = 1;
 221         if ($inview) {
 222                 /;$/ and $inview = 0;
 223                 next;
 224         }
 225
 226         next if /^CREATE RULE/ and $inrule = 1;
 227         if ($inrule) {
 228                 /;$/ and $inrule = 0;
 229                 next;
 230         }
 231
 232         if (/^CREATE TABLE "?(\w+)"? \($/) {
 233                 $table = $1;
 234                 $new{$table}{name}=$table;
 235                 $lastcomma = 1;
 236         }
 237         elsif (/^\);$/) {
 238                 if ($lastcomma) {
 239                         warn "Stray comma before line $.\n";
 240                 }
 241         }
 242         elsif (/^  (\w+) +$dtype.*?(,?)(?: --.*)?$/) {
 243                 $new{$table}{column}{$1} = $2;
 244                 if (!$lastcomma) {
 245                         print "Missing comma before line $. of $new\n";
 246                 }
 247                 $lastcomma = $3 ? 1 : 0;
 248         }
 249         else {
 250                 die "Cannot parse line $. of $new:\n$_\n";
 251         }
 252 }
 253
 254 ## Which column types are okay to map from mysql to postgres?
 255 my $COLMAP = q{
 256 ## INTS:
 257 tinyint SMALLINT
 258 int INTEGER SERIAL
 259 bigint BIGINT
 260 real NUMERIC
 261 float NUMERIC
 262
 263 ## TEXT:
 264 varchar(32) TEXT
 265 varchar(70) TEXT
 266 varchar(255) TEXT
 267 varchar TEXT
 268 text TEXT
 269 tinytext TEXT
 270 ENUM TEXT
 271
 272 ## TIMESTAMPS:
 273 varbinary(14) TIMESTAMPTZ
 274 binary(14) TIMESTAMPTZ
 275 datetime TIMESTAMPTZ
 276 timestamp TIMESTAMPTZ
 277
 278 ## BYTEA:
 279 mediumblob BYTEA
 280
 281 ## OTHER:
 282 bool SMALLINT # Sigh
 283
 284 };
 285 ## Allow specific exceptions to the above
 286 my $COLMAPOK = q{
 287 ## User inputted text strings:
 288 ar_comment      tinyblob       TEXT
 289 fa_description  tinyblob       TEXT
 290 img_description tinyblob       TEXT
 291 ipb_reason      tinyblob       TEXT
 292 log_action      varbinary(10)  TEXT
 293 oi_description  tinyblob       TEXT
 294 rev_comment     tinyblob       TEXT
 295 rc_log_action   varbinary(255) TEXT
 296 rc_log_type     varbinary(255) TEXT
 297
 298 ## Simple text-only strings:
 299 ar_flags          tinyblob       TEXT
 300 fa_minor_mime     varbinary(32)  TEXT
 301 fa_storage_group  varbinary(16)  TEXT # Just 'deleted' for now, should stay plain text
 302 fa_storage_key    varbinary(64)  TEXT # sha1 plus text extension
 303 ipb_address       tinyblob       TEXT # IP address or username
 304 ipb_range_end     tinyblob       TEXT # hexadecimal
 305 ipb_range_start   tinyblob       TEXT # hexadecimal
 306 img_minor_mime    varbinary(32)  TEXT
 307 img_sha1          varbinary(32)  TEXT
 308 job_cmd           varbinary(60)  TEXT # Should we limit to 60 as well?
 309 keyname           varbinary(255) TEXT # No tablename prefix (objectcache)
 310 ll_lang           varbinary(20)  TEXT # Language code
 311 log_params        blob           TEXT # LF separated list of args
 312 log_type          varbinary(10)  TEXT
 313 oi_minor_mime     varbinary(32)  TEXT
 314 oi_sha1           varbinary(32)  TEXT
 315 old_flags         tinyblob       TEXT
 316 old_text          mediumblob     TEXT
 317 pp_propname       varbinary(60)  TEXT
 318 pp_value          blob           TEXT
 319 page_restrictions tinyblob       TEXT # CSV string
 320 pf_server         varchar(30)    TEXT
 321 pr_level          varbinary(60)  TEXT
 322 pr_type           varbinary(60)  TEXT
 323 pt_create_perm    varbinary(60)  TEXT
 324 pt_reason         tinyblob       TEXT
 325 qc_type           varbinary(32)  TEXT
 326 qcc_type          varbinary(32)  TEXT
 327 qci_type          varbinary(32)  TEXT
 328 rc_params         blob           TEXT
 329 ug_group          varbinary(16)  TEXT
 330 user_email_token  binary(32)     TEXT
 331 user_ip           varbinary(40)  TEXT
 332 user_newpassword  tinyblob       TEXT
 333 user_options      blob           TEXT
 334 user_password     tinyblob       TEXT
 335 user_token        binary(32)     TEXT
 336
 337 ## Text URLs:
 338 el_index blob           TEXT
 339 el_to    blob           TEXT
 340 iw_url   blob           TEXT
 341 tb_url   blob           TEXT
 342 tc_url   varbinary(255) TEXT
 343
 344 ## Deprecated or not yet used:
 345 ar_text     mediumblob TEXT
 346 job_params  blob       TEXT
 347 log_deleted tinyint    INTEGER # Not used yet, but keep it INTEGER for safety
 348 rc_type     tinyint    CHAR
 349
 350 ## Number tweaking:
 351 fa_bits   int SMALLINT # bits per pixel
 352 fa_height int SMALLINT
 353 fa_width  int SMALLINT # Hope we don't see an image this wide...
 354 hc_id     int BIGINT   # Odd that site_stats is all bigint...
 355 img_bits  int SMALLINT # bits per image should stay sane
 356 oi_bits   int SMALLINT
 357
 358 ## True binary fields, usually due to gzdeflate and/or serialize:
 359 math_inputhash  varbinary(16) BYTEA
 360 math_outputhash varbinary(16) BYTEA
 361
 362 ## Namespaces: not need for such a high range
 363 ar_namespace   int SMALLINT
 364 job_namespace  int SMALLINT
 365 log_namespace  int SMALLINT
 366 page_namespace int SMALLINT
 367 pl_namespace   int SMALLINT
 368 pt_namespace   int SMALLINT
 369 qc_namespace   int SMALLINT
 370 rc_namespace   int SMALLINT
 371 rd_namespace   int SMALLINT
 372 tl_namespace   int SMALLINT
 373 wl_namespace   int SMALLINT
 374
 375 ## "Bools"
 376 ar_minor_edit    tinyint CHAR
 377 iw_trans         tinyint CHAR
 378 page_is_new      tinyint CHAR
 379 page_is_redirect tinyint CHAR
 380 rc_bot           tinyint CHAR
 381 rc_deleted       tinyint CHAR
 382 rc_minor         tinyint CHAR
 383 rc_new           tinyint CHAR
 384 rc_patrolled     tinyint CHAR
 385 rev_deleted      tinyint CHAR
 386 rev_minor_edit   tinyint CHAR
 387
 388 ## Easy enough to change if a wiki ever does grow this big:
 389 ss_good_articles bigint INTEGER
 390 ss_total_edits   bigint INTEGER
 391 ss_total_pages   bigint INTEGER
 392 ss_total_views   bigint INTEGER
 393 ss_users         bigint INTEGER
 394
 395 ## True IP - keep an eye on these, coders tend to make textual assumptions
 396 rc_ip varbinary(40) CIDR # Want to keep an eye on this
 397
 398 ## Others:
 399 tc_time int TIMESTAMPTZ
 400
 401
 402 };
 403
 404 my %colmap;
 405 for (split /\n/ => $COLMAP) {
 406         next unless /^\w/;
 407         s/(.*?)#.*/$1/;
 408         my ($col,@maps) = split / +/, $_;
 409         for (@maps) {
 410                 $colmap{$col}{$_} = 1;
 411         }
 412 }
 413
 414 my %colmapok;
 415 for (split /\n/ => $COLMAPOK) {
 416         next unless /^\w/;
 417         my ($col,$old,$new) = split / +/, $_;
 418         $colmapok{$col}{$old}{$new} = 1;
 419 }
 420
 421 ## Old but not new
 422 for my $t (sort keys %{$old{$oldfile}}) {
 423         if (!exists $new{$t} and !exists $ok{OLD}{$t}) {
 424                 print "Table not in $new: $t\n";
 425                 next;
 426         }
 427         next if exists $ok{OLD}{$t} and !$ok{OLD}{$t};
 428         my $newt = exists $ok{OLD}{$t} ? $ok{OLD}{$t} : $t;
 429         my $oldcol = $old{$oldfile}{$t}{column};
 430         my $oldcolfull = $old{$oldfile}{$t}{columnfull};
 431         my $newcol = $new{$newt}{column};
 432         for my $c (keys %$oldcol) {
 433                 if (!exists $newcol->{$c}) {
 434                         print "Column $t.$c not in $new\n";
 435                         next;
 436                 }
 437         }
 438         for my $c (sort keys %$newcol) {
 439                 if (!exists $oldcol->{$c}) {
 440                         print "Column $t.$c not in $oldfile\n";
 441                         next;
 442                 }
 443                 ## Column types (roughly) match up?
 444                 my $new = $newcol->{$c};
 445                 my $old = $oldcolfull->{$c};
 446
 447                 ## Known exceptions:
 448                 next if exists $colmapok{$c}{$old}{$new};
 449
 450                 $old =~ s/ENUM.*/ENUM/;
 451                 if (! exists $colmap{$old}{$new}) {
 452                         print "Column types for $t.$c do not match: $old does not map to $new\n";
 453                 }
 454         }
 455 }
 456 ## New but not old:
 457 for (sort keys %new) {
 458         if (!exists $old{$oldfile}{$_} and !exists $ok{NEW}{$_}) {
 459                 print "Not in $oldfile: $_\n";
 460                 next;
 461         }
 462 }
 463
 464
 465 } ## end each file to be parsed
 466
 467
 468 __DATA__
 469 ## Known exceptions
 470 OLD: searchindex          ## We use tsearch2 directly on the page table instead
 471 RENAME: user mwuser       ## Reserved word causing lots of problems
 472 RENAME: text pagecontent  ## Reserved word
 473 NEW: mediawiki_version    ## Just us, for now
 474 XFILE: ../archives/patch-profiling.sql