maintenance/postgres/compare_schemas.pl

   1 #!/usr/bin/perl
   2
   3 ## Rough check that the base and postgres "tables.sql" are in sync
   4 ## Should be run from maintenance/postgres
   5
   6 use strict;
   7 use warnings;
   8 use Data::Dumper;
   9
  10 my @old = ('../tables.sql');
  11 my $new = 'tables.sql';
  12 my @xfile;
  13
  14 ## Read in exceptions and other metadata
  15 my %ok;
  16 while (<DATA>) {
  17         next unless /^(\w+)\s*:\s*([^#]+)/;
  18         my ($name,$val) = ($1,$2);
  19         chomp $val;
  20         if ($name eq 'RENAME') {
  21                 die "Invalid rename\n" unless $val =~ /(\w+)\s+(\w+)/;
  22                 $ok{OLD}{$1} = $2;
  23                 $ok{NEW}{$2} = $1;
  24                 next;
  25         }
  26         if ($name eq 'XFILE') {
  27                 push @xfile, $val;
  28                 next;
  29         }
  30         for (split /\s+/ => $val) {
  31                 $ok{$name}{$_} = 0;
  32         }
  33 }
  34
  35 my $datatype = join '|' => qw(
  36 bool
  37 tinyint int bigint real float
  38 tinytext mediumtext text char varchar varbinary binary
  39 timestamp datetime
  40 tinyblob mediumblob blob
  41 );
  42 $datatype .= q{|ENUM\([\"\w, ]+\)};
  43 $datatype = qr{($datatype)};
  44
  45 my $typeval = qr{(\(\d+\))?};
  46
  47 my $typeval2 = qr{ unsigned| binary| NOT NULL| NULL| auto_increment| default ['\-\d\w"]+| REFERENCES .+CASCADE};
  48
  49 my $indextype = join '|' => qw(INDEX KEY FULLTEXT), 'PRIMARY KEY', 'UNIQUE INDEX', 'UNIQUE KEY';
  50 $indextype = qr{$indextype};
  51
  52 my $engine = qr{TYPE|ENGINE};
  53
  54 my $tabletype = qr{InnoDB|MyISAM|HEAP|HEAP MAX_ROWS=\d+|InnoDB MAX_ROWS=\d+ AVG_ROW_LENGTH=\d+};
  55
  56 my $charset = qr{utf8|binary};
  57
  58 open my $newfh, '<', $new or die qq{Could not open $new: $!\n};
  59
  60
  61 my ($table,%old);
  62
  63 ## Read in the xfiles
  64 my %xinfo;
  65 for my $xfile (@xfile) {
  66         print "Loading $xfile\n";
  67         my $info = &parse_sql($xfile);
  68         for (keys %$info) {
  69                 $xinfo{$_} = $info->{$_};
  70         }
  71 }
  72
  73 for my $oldfile (@old) {
  74         print "Loading $oldfile\n";
  75         my $info = &parse_sql($oldfile);
  76         for (keys %xinfo) {
  77                 $info->{$_} = $xinfo{$_};
  78         }
  79         $old{$oldfile} = $info;
  80 }
  81
  82 sub parse_sql {
  83
  84         my $oldfile = shift;
  85
  86         open my $oldfh, '<', $oldfile or die qq{Could not open $oldfile: $!\n};
  87
  88         my %info;
  89         while (<$oldfh>) {
  90                 next if /^\s*\-\-/ or /^\s+$/;
  91                 s/\s*\-\- [\w ]+$//;
  92                 chomp;
  93
  94                 if (/CREATE\s*TABLE/i) {
  95                         m{^CREATE TABLE /\*\$wgDBprefix\*/(\w+) \($}
  96                                 or die qq{Invalid CREATE TABLE at line $. of $oldfile\n};
  97                         $table = $1;
  98                         $info{$table}{name}=$table;
  99                 }
 100                 elsif (m#^\) /\*\$wgDBTableOptions\*/#) {
 101                         $info{$table}{engine} = 'TYPE';
 102                         $info{$table}{type} = 'variable';
 103                 }
 104                 elsif (/^\) ($engine)=($tabletype);$/) {
 105                         $info{$table}{engine}=$1;
 106                         $info{$table}{type}=$2;
 107                 }
 108                 elsif (/^\) ($engine)=($tabletype), DEFAULT CHARSET=($charset);$/) {
 109                         $info{$table}{engine}=$1;
 110                         $info{$table}{type}=$2;
 111                         $info{$table}{charset}=$3;
 112                 }
 113                 elsif (/^  (\w+) $datatype$typeval$typeval2{0,3},?$/) {
 114                         $info{$table}{column}{$1} = $2;
 115                         my $extra = $3 || '';
 116                         $info{$table}{columnfull}{$1} = "$2$extra";
 117                 }
 118                 elsif (/^  ($indextype)(?: (\w+))? \(([\w, \(\)]+)\),?$/) {
 119                         $info{$table}{lc $1.'_name'} = $2 ? $2 : '';
 120                         $info{$table}{lc $1.'pk_target'} = $3;
 121                 }
 122                 else {
 123                         die "Cannot parse line $. of $oldfile:\n$_\n";
 124                 }
 125
 126         }
 127         close $oldfh;
 128
 129         return \%info;
 130
 131 } ## end of parse_sql
 132
 133 ## Read in the parser test information
 134 my $parsefile = '../parserTests.inc';
 135 open my $pfh, '<', $parsefile or die qq{Could not open "$parsefile": $!\n};
 136 my $stat = 0;
 137 my %ptable;
 138 while (<$pfh>) {
 139         if (!$stat) {
 140                 if (/function listTables/) {
 141                         $stat = 1;
 142                 }
 143                 next;
 144         }
 145         $ptable{$1}=2 while /'(\w+)'/g;
 146         last if /;/;
 147 }
 148 close $pfh;
 149
 150 my $OK_NOT_IN_PTABLE = '
 151 filearchive
 152 logging
 153 profiling
 154 querycache_info
 155 trackbacks
 156 transcache
 157 user_newtalk
 158 ';
 159
 160 ## Make sure all tables in main tables.sql are accounted for int the parsertest.
 161 for my $table (sort keys %{$old{'../tables.sql'}}) {
 162         $ptable{$table}++;
 163         next if $ptable{$table} > 2;
 164         next if $OK_NOT_IN_PTABLE =~ /\b$table\b/;
 165         print qq{Table "$table" is in the schema, but not used inside of parserTest.inc\n};
 166 }
 167 ## Any that are used in ptables but no longer exist in the schema?
 168 for my $table (sort grep { $ptable{$_} == 2 } keys %ptable) {
 169         print qq{Table "$table" ($ptable{$table}) used in parserTest.inc, but not found in schema\n};
 170 }
 171
 172 for my $oldfile (@old) {
 173
 174 ## Begin non-standard indent
 175
 176 ## MySQL sanity checks
 177 for my $table (sort keys %{$old{$oldfile}}) {
 178         my $t = $old{$oldfile}{$table};
 179         if (($oldfile =~ /5/ and $t->{engine} ne 'ENGINE')
 180                 or
 181                 ($oldfile !~ /5/ and $t->{engine} ne 'TYPE')) {
 182                 die "Invalid engine for $oldfile: $t->{engine}\n" unless $t->{name} eq 'profiling';
 183         }
 184         my $charset = $t->{charset} || '';
 185         if ($oldfile !~ /binary/ and $charset eq 'binary') {
 186                 die "Invalid charset for $oldfile: $charset\n";
 187         }
 188 }
 189
 190 my $dtype = join '|' => qw(
 191 SMALLINT INTEGER BIGINT NUMERIC SERIAL
 192 TEXT CHAR VARCHAR
 193 BYTEA
 194 TIMESTAMPTZ
 195 CIDR
 196 );
 197 $dtype = qr{($dtype)};
 198 my %new;
 199 my ($infunction,$inview,$inrule,$lastcomma) = (0,0,0,0);
 200 seek $newfh, 0, 0;
 201 while (<$newfh>) {
 202         next if /^\s*\-\-/ or /^\s*$/;
 203         s/\s*\-\- [\w ']+$//;
 204         next if /^BEGIN;/ or /^SET / or /^COMMIT;/;
 205         next if /^CREATE SEQUENCE/;
 206         next if /^CREATE(?: UNIQUE)? INDEX/;
 207         next if /^CREATE FUNCTION/;
 208         next if /^CREATE TRIGGER/ or /^  FOR EACH ROW/;
 209         next if /^INSERT INTO/ or /^  VALUES \(/;
 210         next if /^ALTER TABLE/;
 211         chomp;
 212
 213         if (/^\$mw\$;?$/) {
 214                 $infunction = $infunction ? 0 : 1;
 215                 next;
 216         }
 217         next if $infunction;
 218
 219         next if /^CREATE VIEW/ and $inview = 1;
 220         if ($inview) {
 221                 /;$/ and $inview = 0;
 222                 next;
 223         }
 224
 225         next if /^CREATE RULE/ and $inrule = 1;
 226         if ($inrule) {
 227                 /;$/ and $inrule = 0;
 228                 next;
 229         }
 230
 231         if (/^CREATE TABLE "?(\w+)"? \($/) {
 232                 $table = $1;
 233                 $new{$table}{name}=$table;
 234                 $lastcomma = 1;
 235         }
 236         elsif (/^\);$/) {
 237                 if ($lastcomma) {
 238                         warn "Stray comma before line $.\n";
 239                 }
 240         }
 241         elsif (/^  (\w+) +$dtype.*?(,?)(?: --.*)?$/) {
 242                 $new{$table}{column}{$1} = $2;
 243                 if (!$lastcomma) {
 244                         print "Missing comma before line $. of $new\n";
 245                 }
 246                 $lastcomma = $3 ? 1 : 0;
 247         }
 248         else {
 249                 die "Cannot parse line $. of $new:\n$_\n";
 250         }
 251 }
 252
 253 ## Which column types are okay to map from mysql to postgres?
 254 my $COLMAP = q{
 255 ## INTS:
 256 tinyint SMALLINT
 257 int INTEGER SERIAL
 258 bigint BIGINT
 259 real NUMERIC
 260 float NUMERIC
 261
 262 ## TEXT:
 263 varchar(32) TEXT
 264 varchar(70) TEXT
 265 varchar(255) TEXT
 266 varchar TEXT
 267 text TEXT
 268 tinytext TEXT
 269 ENUM TEXT
 270
 271 ## TIMESTAMPS:
 272 varbinary(14) TIMESTAMPTZ
 273 binary(14) TIMESTAMPTZ
 274 datetime TIMESTAMPTZ
 275 timestamp TIMESTAMPTZ
 276
 277 ## BYTEA:
 278 mediumblob BYTEA
 279
 280 ## OTHER:
 281 bool CHAR # Sigh
 282
 283 };
 284 ## Allow specific exceptions to the above
 285 my $COLMAPOK = q{
 286 ## User inputted text strings:
 287 ar_comment      tinyblob       TEXT
 288 fa_description  tinyblob       TEXT
 289 img_description tinyblob       TEXT
 290 ipb_reason      tinyblob       TEXT
 291 log_action      varbinary(10)  TEXT
 292 oi_description  tinyblob       TEXT
 293 rev_comment     tinyblob       TEXT
 294 rc_log_action   varbinary(255) TEXT
 295 rc_log_type     varbinary(255) TEXT
 296
 297 ## Simple text-only strings:
 298 ar_flags          tinyblob       TEXT
 299 fa_minor_mime     varbinary(32)  TEXT
 300 fa_storage_group  varbinary(16)  TEXT # Just 'deleted' for now, should stay plain text
 301 fa_storage_key    varbinary(64)  TEXT # sha1 plus text extension
 302 ipb_address       tinyblob       TEXT # IP address or username
 303 ipb_range_end     tinyblob       TEXT # hexadecimal
 304 ipb_range_start   tinyblob       TEXT # hexadecimal
 305 img_minor_mime    varbinary(32)  TEXT
 306 img_sha1          varbinary(32)  TEXT
 307 job_cmd           varbinary(60)  TEXT # Should we limit to 60 as well?
 308 keyname           varbinary(255) TEXT # No tablename prefix (objectcache)
 309 ll_lang           varbinary(20)  TEXT # Language code
 310 log_params        blob           TEXT # LF separated list of args
 311 log_type          varbinary(10)  TEXT
 312 oi_minor_mime     varbinary(32)  TEXT
 313 oi_sha1           varbinary(32)  TEXT
 314 old_flags         tinyblob       TEXT
 315 old_text          mediumblob     TEXT
 316 page_restrictions tinyblob       TEXT # CSV string
 317 pf_server         varchar(30)    TEXT
 318 pr_level          varbinary(60)  TEXT
 319 pr_type           varbinary(60)  TEXT
 320 pt_create_perm    varbinary(60)  TEXT
 321 pt_reason         tinyblob       TEXT
 322 qc_type           varbinary(32)  TEXT
 323 qcc_type          varbinary(32)  TEXT
 324 qci_type          varbinary(32)  TEXT
 325 rc_params         blob           TEXT
 326 ug_group          varbinary(16)  TEXT
 327 user_email_token  binary(32)     TEXT
 328 user_ip           varbinary(40)  TEXT
 329 user_newpassword  tinyblob       TEXT
 330 user_options      blob           TEXT
 331 user_password     tinyblob       TEXT
 332 user_token        binary(32)     TEXT
 333
 334 ## Text URLs:
 335 el_index blob           TEXT
 336 el_to    blob           TEXT
 337 iw_url   blob           TEXT
 338 tb_url   blob           TEXT
 339 tc_url   varbinary(255) TEXT
 340
 341 ## Deprecated or not yet used:
 342 ar_text     mediumblob TEXT
 343 job_params  blob       TEXT
 344 log_deleted tinyint    INTEGER # Not used yet, but keep it INTEGER for safety
 345 rc_type     tinyint    CHAR
 346
 347 ## Number tweaking:
 348 fa_bits   int SMALLINT # bits per pixel
 349 fa_height int SMALLINT
 350 fa_width  int SMALLINT # Hope we don't see an image this wide...
 351 hc_id     int BIGINT   # Odd that site_stats is all bigint...
 352 img_bits  int SMALLINT # bits per image should stay sane
 353 oi_bits   int SMALLINT
 354
 355 ## True binary fields, usually due to gzdeflate and/or serialize:
 356 math_inputhash  varbinary(16) BYTEA
 357 math_outputhash varbinary(16) BYTEA
 358
 359 ## Namespaces: not need for such a high range
 360 ar_namespace   int SMALLINT
 361 job_namespace  int SMALLINT
 362 log_namespace  int SMALLINT
 363 page_namespace int SMALLINT
 364 pl_namespace   int SMALLINT
 365 pt_namespace   int SMALLINT
 366 qc_namespace   int SMALLINT
 367 rc_namespace   int SMALLINT
 368 rd_namespace   int SMALLINT
 369 tl_namespace   int SMALLINT
 370 wl_namespace   int SMALLINT
 371
 372 ## "Bools"
 373 ar_minor_edit    tinyint CHAR
 374 iw_trans         tinyint CHAR
 375 page_is_new      tinyint CHAR
 376 page_is_redirect tinyint CHAR
 377 rc_bot           tinyint CHAR
 378 rc_deleted       tinyint CHAR
 379 rc_minor         tinyint CHAR
 380 rc_new           tinyint CHAR
 381 rc_patrolled     tinyint CHAR
 382 rev_deleted      tinyint CHAR
 383 rev_minor_edit   tinyint CHAR
 384
 385 ## Easy enough to change if a wiki ever does grow this big:
 386 ss_good_articles bigint INTEGER
 387 ss_total_edits   bigint INTEGER
 388 ss_total_pages   bigint INTEGER
 389 ss_total_views   bigint INTEGER
 390 ss_users         bigint INTEGER
 391
 392 ## True IP - keep an eye on these, coders tend to make textual assumptions
 393 rc_ip varbinary(40) CIDR # Want to keep an eye on this
 394
 395 ## Others:
 396 tc_time int TIMESTAMPTZ
 397
 398
 399 };
 400
 401 my %colmap;
 402 for (split /\n/ => $COLMAP) {
 403         next unless /^\w/;
 404         s/(.*?)#.*/$1/;
 405         my ($col,@maps) = split / +/, $_;
 406         for (@maps) {
 407                 $colmap{$col}{$_} = 1;
 408         }
 409 }
 410
 411 my %colmapok;
 412 for (split /\n/ => $COLMAPOK) {
 413         next unless /^\w/;
 414         my ($col,$old,$new) = split / +/, $_;
 415         $colmapok{$col}{$old}{$new} = 1;
 416 }
 417
 418 ## Old but not new
 419 for my $t (sort keys %{$old{$oldfile}}) {
 420         if (!exists $new{$t} and !exists $ok{OLD}{$t}) {
 421                 print "Table not in $new: $t\n";
 422                 next;
 423         }
 424         next if exists $ok{OLD}{$t} and !$ok{OLD}{$t};
 425         my $newt = exists $ok{OLD}{$t} ? $ok{OLD}{$t} : $t;
 426         my $oldcol = $old{$oldfile}{$t}{column};
 427         my $oldcolfull = $old{$oldfile}{$t}{columnfull};
 428         my $newcol = $new{$newt}{column};
 429         for my $c (keys %$oldcol) {
 430                 if (!exists $newcol->{$c}) {
 431                         print "Column $t.$c not in $new\n";
 432                         next;
 433                 }
 434         }
 435         for my $c (sort keys %$newcol) {
 436                 if (!exists $oldcol->{$c}) {
 437                         print "Column $t.$c not in $oldfile\n";
 438                         next;
 439                 }
 440                 ## Column types (roughly) match up?
 441                 my $new = $newcol->{$c};
 442                 my $old = $oldcolfull->{$c};
 443
 444                 ## Known exceptions:
 445                 next if exists $colmapok{$c}{$old}{$new};
 446
 447                 $old =~ s/ENUM.*/ENUM/;
 448                 if (! exists $colmap{$old}{$new}) {
 449                         print "Column types for $t.$c do not match: $old does not map to $new\n";
 450                 }
 451         }
 452 }
 453 ## New but not old:
 454 for (sort keys %new) {
 455         if (!exists $old{$oldfile}{$_} and !exists $ok{NEW}{$_}) {
 456                 print "Not in $oldfile: $_\n";
 457                 next;
 458         }
 459 }
 460
 461
 462 } ## end each file to be parsed
 463
 464
 465 __DATA__
 466 ## Known exceptions
 467 OLD: searchindex          ## We use tsearch2 directly on the page table instead
 468 RENAME: user mwuser       ## Reserved word causing lots of problems
 469 RENAME: text pagecontent  ## Reserved word
 470 NEW: mediawiki_version    ## Just us, for now
 471 XFILE: ../archives/patch-profiling.sql